概括

要统计已售商品数量和剩余商品数量，可以使用COUNTA 函数。在所示示例中，F7 单元格中的公式为：

=COUNTA(B5:B16)-COUNTA(C5:C16)

结果为 5，因为 12 件商品中已售出 7 件。您也可以使用COUNTIF 函数来解决这个问题。以下将介绍这两种方法。

通用公式

=COUNTA(range1)-COUNTA(range2)

解释

在这个例子中，目标是根据 B 列和 C 列中的数据，统计已售商品和剩余商品的数量。ID 列包含唯一的 ID，Sold 列用于记录销售情况。Sold 列中的“x”表示该商品已售出。与 Excel 中的其他问题一样，解决此问题有多种方法。以下文章将介绍其中两种方法。

COUNTA 函数

COUNTA函数用于统计指定区域中非空单元格的数量。与仅统计数值的 COUNT 函数不同， COUNTA 函数可以统计单元格中的任何值，包括数字和文本。F5 单元格中的第一个公式用于统计可用商品的总数：

=COUNTA(B5:B16) // returns 12

结果为 12，因为 ID 列中有 12 个值。第二个公式统计已售商品的数量：

=COUNTA(C5:C16) // returns 7

结果为 7，因为“已售”列中有 7 个值。请注意，COUNTA 函数并不关心单元格中的值是什么。在所示示例中，我们使用“x”表示已售商品，但 COUNTA 函数也会以相同的方式统计“y”或“z”。最后一个公式计算剩余商品的数量：

=COUNTA(B5:B16)-COUNTA(C5:C16) // returns 5

结果为 5，因为 12 减 7 等于 5。在这个例子中，上面的最后一个公式是一个包含所有计算步骤的公式，以便提供更多细节。但是，在这个特定情况下，最佳实践是将最后一个公式写成这样：

=F5-F6 // use existing values

换句话说，我们只是简单地重复利用已有的结果。这最大限度地减少了计算次数，并降低了误差。

COUNTIF 函数

COUNTIF 函数根据提供的条件统计指定范围内的值。使用 COUNTIF 函数可以采用略有不同的方法来解决这个问题。要统计项目总数，您可以像这样使用 COUNTIF 函数：

=COUNTIF(B5:B16,"<>") // count not blank

要统计已售商品数量，您可以使用以下任一公式：

=COUNTIF(C5:C16,"x") // count equal to "x"
=COUNTIF(C5:C16,"<>") // count not blank

要统计未售出的商品数量，可以使用 COUNTIF 函数，如下所示：

=COUNTIF(C5:C16,"") // count blank

匹配测试

如果您需要确保同一行中 C 列的值与 B 列的值匹配，则可以使用基于SUMPRODUCT 函数的公式 ：

=SUMPRODUCT(--(B5:B11=C5:C11))